Read a File Line by Line - and More.

Category:

Files and Directories

Type:

Snippets

Difficulty:

Beginning

Author:

Anonymous

Version Compatibility: Visual Basic 6

More information:

If you call this function while supplying just the file name, then every time you call it you get the next line of the file. You can supply a line number if you know which line you need. You can also reset the read cursor to the beginning of the file - all without making any changes to the code. Also an example of basic error handling.

Instructions: Copy the declarations and code below and paste directly into your VB project.

Declarations:
N/A

Code:

Public Function ReadLineByLine(FileName As String, Optional LineNum As Long, _
    Optional Reset As Boolean) As String
    
    Static lLineCount As Long
    Dim nLineCounter As Long, nFileNum As Integer, sText As String, _
        sNextLine As String
    
    ' We can't start looking at line number 0...
    If lLineCount = 0 Then lLineCount = 1
    
    ' initialize our non static counter
    nLineCounter = 1

' Get a free file number
    nFileNum = FreeFile
    
    ' Do we need to start at the beginning of the file?
    If Reset = True Then lLineCount = 1
    
    ' If there's an error reading the file, we don't want the
    ' app to just roll over.
    On Error GoTo ErrHandler
    
    ' Open FileName for input.
    Open FileName For Input As nFileNum
    
    ' --------------------------------If we're looking for a specific line...
    If LineNum <> 0 Then
    
        ' Read the contents of the file
        Do While Not EOF(nFileNum)
            
            Line Input #nFileNum, sNextLine
            
            If LineNum = nLineCounter Then
                ReadLineByLine = sNextLine
                Close nFileNum
                Exit Function
            End If
            
            nLineCounter = nLineCounter + 1
        Loop
        
        ' What if we were looking for a line that didn't exist in this file?
        If nLineCounter < LineNum Then
            ReadLineByLine = "<EOF>" ' Tell em we're at the end of the file
            Close nFileNum
            Exit Function
        End If
    
    End If
    
    ' ------------------------------------------------------------------------
    ' -----------------------------------If we're just reading the next line...
    
    ' Read the contents of the file
    Do While Not EOF(nFileNum)
        
        Line Input #nFileNum, sNextLine
        
        If nLineCounter = lLineCount Then
            ReadLineByLine = sNextLine
            lLineCount = lLineCount + 1
            Exit Do ' We only want this one
        End If
        
        nLineCounter = nLineCounter + 1
            
    Loop
    
    ' Were we at the end of this file?
    If EOF(nFileNum) And ReadLineByLine = "" Then
        ReadLineByLine = "<EOF>" ' Tell em we're at the end of the file
        lLineCount = 1 ' Reset the counter to the beginning of the file
    End If
    
GoTo Skip

ErrHandler:
    
    MsgBox "There was an error reading from file " & FileName & ". " & _
        "The error returned is: " & Err & Chr(13) & Chr(13) & _
        "", vbExclamation, "Message Box Title Here."
    
    On Error Resume Next ' Make sure the app doesn't roll over
                         ' when we attempt to close the file
    
Skip:
    
    ' Close the file
    Close nFileNum

End Function