Load Sequential File to Array and Loop through it Forwards and Backwards

Category:

Lists, Collections and Arrays

Type:

Snippets

Difficulty:

Beginning

Author:

Anonymous

Version Compatibility: Visual Basic 6, Visual Basic 5

More information:

This simple example shows how to load a sequential text file into an array and then move through the array forwards and backwards using a control variable. The example uses two command buttons for "Previous" and "Next" and displays the current array item in a label. To use this code start a new project in VB and paste the code into the declarations section of Form1. Press F5 to run the code.

Instructions: Copy the declarations and code below and paste directly into your VB project.

Declarations:
' (None)

Code:

'our control variable to tell where we are in the array
Private iControl As Integer
'tells us whether the file has been loaded yet.
Private bIsLoaded As Boolean
'array to hold items from the file
Private FileItems() As String

Private Sub LoadFile()

'this procedure loads the items from the dummy file and 
     'populates an array

Dim x As Integer
    Dim iFreeFile As Integer
    
    iFreeFile = FreeFile
    'open the file and loop through it
    Open "C:\test.txt" For Input As iFreeFile
        Do While Not EOF(iFreeFile)
            ' 'x' is our counter here. We will 
             'redemension the array after 
             'every 25 items have been added
            If x Mod 25 = 0 Then
                'if 'x' is zero then the array is empty
                If x = 0 Then
                    'create 25 elements in the array
                    ReDim FileItems(25)
                Else
                    ' when it gets here x will be 25 or 50 or 75 or ...
                    ' we need to increase the size of the array to hold more items
                    
                    ' use the 'Preserve' keyword so we don't erase the other items
                    ' we've already stored in the array.
                    
                    ' use the 'UBound' keyword to find out the current size of the array
                    ' then add 25 to it to resize the array.
                    ReDim Preserve FileItems(UBound(FileItems) + 25)
                End If
            End If
            
            'get an item from the file and add it to the array
            Line Input #iFreeFile, FileItems(x)
            'increment the counter
            x = x + 1
        Loop
    Close iFreeFile
    
    'resize the array one final time to get rid of unused elements at the end.
    ReDim Preserve FileItems(x)
    
    bIsLoaded = True
    
End Sub

Private Sub Command1_Click()
    'this is the 'Previous' button
    
    
    'if the file has not been loaded in to the array yet then do so
    If Not bIsLoaded Then
        LoadFile
    End If
    
    'reduce control variable by 1
    iControl = iControl - 1
    'make sure it is not less than zero.
    'if it is then set it to zero so we don't
    'get a 'subscript out of range' error.
    If iControl < 0 Then
        iControl = 0
    End If
    
    'display the item
    Label1.Caption = FileItems(iControl)
End Sub

Private Sub Command2_Click()
    'this is our 'Next' button
    
    
    'if the file has not been loaded in to the array yet then do so
    If Not bIsLoaded Then
        LoadFile
    End If

'increment the control variable by 1
    iControl = iControl + 1
    'see if it is out of range.
    'if so set it to the highest possible number of the array
    'so we don't generate a 'subscript out of range' error
    If iControl > UBound(FileItems) - 1 Then
        iControl = UBound(FileItems) - 1
    End If
    
    'display the item
    Label1.Caption = FileItems(iControl)

End Sub

Private Sub Form_Load()
    Dim x As Integer
    Dim iFreeFile As Integer
    
    'set up label and command captions
    Label1.Caption = ""
    Command1.Caption = "< &Previous"
    Command2.Caption = "&Next >"
    
    'create a dummy file with the numbers 1 through 57
    'we will read these in to an array in the LoadFile routine
    iFreeFile = FreeFile
    Open "C:\test.txt" For Output As iFreeFile
        For x = 1 To 57
            Print #iFreeFile, Str$(x)
        Next
    Close iFreeFile
        
End Sub