Check If a Process is Running on a Remote Computer (VB Script)

Category:

Network/Internet

Type:

Snippets

Difficulty:

Intermediate

Author:

Rowen Bankx

Version Compatibility: Visual Basic Script

More information:

This script checks if a specific process is running on a (remote) computer. It uses WMI to accomplish this. Check out http://www.activxperts.com for more samples, components and tools

Instructions: Copy the declarations and code below and paste directly into your VB project.

Declarations:
' (None)

Code:

' *****************************************************************
' This function checks if a process is running on a (remote) computer
' Requires WMI
' *****************************************************************
' Check out http://www.activxperts.com for more samples and components
' ****************************************************************************

Function IsProcessRunning( strServer, strProcess )
    Dim Process, strObject
    IsProcessRunning = False
    strObject   = "winmgmts://" & strServer
    For Each Process in GetObject( strObject ).InstancesOf( "win32_process" )
	If UCase( Process.name ) = UCase( strProcess ) Then
            IsProcessRunning = True
            Exit Function
        End If
    Next
End Function

' ****************************************************************************
' Main
' ****************************************************************************
Dim strComputer, strProcess
Do
   strProcess = inputbox( "Please enter the name of the process (for instance: explorer.exe)", "Input" )
Loop until strProcess <> ""
Do
   strComputer = inputbox( "Please enter the computer name", "Input" )
Loop until strComputer <> ""
If( IsProcessRunning( strComputer, strProcess ) = True ) Then
    WScript.Echo "Process " & strProcess & " is running on computer " & strComputer
Else
    WScript.Echo "Process " & strProcess & " is NOT running on computer " & strComputer
End If