Check if Printer is Available on a Remote Print Server (VB Script)

Category:

Network/Internet

Type:

Snippets

Difficulty:

Intermediate

Author:

Rowen Bankx

Version Compatibility: Visual Basic Script

More information:

This script checks if a printer is available on a (remote) printserver. It uses WMI to accomplish this. Check out http://www.activxperts.com for more samples, components and tools

Instructions: Copy the declarations and code below and paste directly into your VB project.

Declarations:
' (None)

Code:

' *****************************************************************
' This function checks if a printer is up-and-running
' Requires WMI
' *****************************************************************
' Check out http://www.activxperts.com for more samples and components
' *****************************************************************

Const PrinterIdle = 3
Const PrinterPrinting = 4
Const PrinterWarmingUp = 5

Function IsPrinterUp( strPrintServer, strPrinter )
    Dim strobject, PrinterSet, Printer

IsPrinterUp = False

strObject = "winmgmts://" & strPrintServer
    Set PrinterSet = GetObject( strObject ).InstancesOf( "win32_Printer" )
    If( PrinterSet.Count = 0 ) Then 
        Exit Function
    End If

For Each Printer in PrinterSet 
        WScript.Echo Printer.Name & " ==> " & Printer.PrinterStatus 
        If UCase( Printer.name ) = UCase( strPrinter  ) Then
	       If Printer.PrinterStatus = PrinterIdle Or Printer.PrinterStatus = PrinterPrinting Or Printer.PrinterStatus = PrinterWarmingUp Then
                IsPrinterUp = True
                Exit Function
           End If 
        End If           
    Next
	
End Function

' *****************************************************************
' Main
' *****************************************************************
Dim strPrintServer, strPrinterName
Do
   strPrinterName = inputbox( "Please enter the name of the printer", "Input" )
Loop until strPrinterName <> ""
Do
   strPrintServer = inputbox( "Please enter the name of the printserver", "Input" )
Loop until strPrintServer <> ""
If( IsPrinterUp( strPrintServer, strPrinterName ) = True ) Then
    WScript.Echo "Printer " & strPrinterName & " is OK"
Else
    WScript.Echo "Printer " & strPrinterName & " is NOT OK"
End If