Retrieve the Captions of All Open Top-Level Windows

Category:

System/API

Type:

Snippets

Difficulty:

Intermediate

Author:

Intelligent Solutions Inc.

Version Compatibility: Visual Basic 6

More information:

This example uses the AddressOf Operator to return a string array containing the window titles of all open top level windows.

Instructions: Copy the declarations and code below and paste directly into your VB project.

Declarations:
'PUT ALL THIS CODE (DECLARATIONS AND FUNCTIONS) 'INTO A .BAS MODULE. Option Explicit Private Declare Function EnumWindows Lib "user32" _ (ByVal lpEnumFunc As Long, ByVal lParam As Long) As Long Private Declare Function GetWindowText Lib "user32" Alias _ "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, _ ByVal cch As Long) As Long Private asTopLevelWindows() As String

Code:

Public Function TopLevelWindows() As String()

'PURPOSE: RETURNS AN ARRAY OF TOPLEVEL WINDOWS
'REQUIRES: VB 6
'SAMPLE:
'Dim sArray() As String
'Dim iCtr As Integer

'sArray = TopLevelWindows
'For iCtr = 0 To UBound(sArray)
'Debug.Print sArray(iCtr)
'Next

ReDim asTopLevelWindows(0) As String
Dim lRet As Long
lRet = EnumWindows(AddressOf AddElement, 0)
TopLevelWindows = asTopLevelWindows
End Function
Private Function AddElement(ByVal lhWnd As Long, ByVal lParam As Long) As Long

Dim sTitle As String
Dim lRet As Long
Dim iNew As Integer

sTitle = Space(255)
lRet = GetWindowText(lhWnd, sTitle, 255)

sTitle = StripNull(sTitle)

If sTitle <> "" Then
    If asTopLevelWindows(0) = "" Then
        iNew = 0
    Else
        iNew = UBound(asTopLevelWindows) + 1
        ReDim Preserve asTopLevelWindows(iNew) As String
    End If
    
    asTopLevelWindows(iNew) = sTitle

End If

AddElement = True

End Function

Private Function StripNull(ByVal InString As String) As String

'Input: String containing null terminator (Chr(0))
'Returns: all character before the null terminator

Dim iNull As Integer
If Len(InString) > 0 Then
    iNull = InStr(InString, vbNullChar)
    Select Case iNull
    Case 0
        StripNull = InString
    Case 1
        StripNull = ""
    Case Else
       StripNull = Left$(InString, iNull - 1)
   End Select
End If

End Function