Convert 1D Arrays to 2D Arrays and Back

Category:

Lists, Collections and Arrays

Type:

Snippets

Difficulty:

Advanced

Author:

neophile

Version Compatibility: Visual Basic 6

More information:

Here's another demonstration of the extremely useful CopyMemory() API call, a.k.a. RtlMoveMemory. I've used Byte arrays in this example, but it should work for any array with elements of a fixed length (i.e., since strings vary in length, this is probably not a good idea unless you write a new procedure to handle them explicitly.) Also, this can be adapted to deal with 3+ dimensions as well.

Instructions: Copy the declarations and code below and paste directly into your VB project.

Declarations:
Option Explicit Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (pDst As Any, pSrc As Any, ByVal ByteLen As Long)

Code:

Public Function Bytes1Dto2D(Bytes1D() As Byte, ByVal SizeX As Long, Optional ResultY As Long) As Byte()
' Will size 2nd dimension so all data fits and return it's
' size (not boundary) in 'ResultY'
    Dim bMem() As Byte
   
    ResultY = -(Int(-(UBound(Bytes1D) + 1) / SizeX))
    ReDim bMem(SizeX - 1, ResultY - 1)
    Call CopyMemory(bMem(0, 0), Bytes1D(0), UBound(Bytes1D) + 1)
    Bytes1Dto2D = bMem
    Erase bMem
End Function

Public Function Bytes2Dto1D(Bytes2D() As Byte) As Byte()
    Dim bMem() As Byte
    Dim lSize As Long
    
    lSize = (UBound(Bytes2D, 1) + 1) * (UBound(Bytes2D, 2) + 1)
    ReDim bMem(lSize - 1)
    Call CopyMemory(bMem(0), Bytes2D(0, 0), lSize)
    Bytes2Dto1D = bMem
    Erase bMem
End Function

Public Sub Test(ByVal NewX As Long)
' A sample demonstration that works with a 10-element 1D array 
   Dim bTmp() As Byte
   Dim x As Integer
   Dim y As Integer
   Dim lB2 As Long
   
   ReDim bTmp(9)
   For x = 0 To 9
      bTmp(x) = x
   Next
   bTmp = Bytes1Dto2D(bTmp, NewX)
   For y = 0 To UBound(bTmp, 2)
      For x = 0 To NewX - 1
         Debug.Print bTmp(x, y);
      Next
      Debug.Print
   Next
   bTmp = Bytes2Dto1D(bTmp)
   For x = 0 To UBound(bTmp)
      Debug.Print bTmp(x);
   Next
   Debug.Print
   Erase bTmp
End Sub