Sort Date Column in ListView without Using API

Category:

Forms and Controls

Type:

Snippets

Difficulty:

Intermediate

Author:

Mitesh H. Budhabhatti

Version Compatibility: Visual Basic 6, Visual Basic 5

More information:

The listview control cannot sort date column. It sorts date column as normal text. This piece of code displays how to sort date column in Listview without using API. For this you have to add a listview to the form and copy/paste the code.

Instructions: Copy the declarations and code below and paste directly into your VB project.

Declarations:
' (None)

Code:

Private Sub Form_Load()
    Dim oListItem As MSComctlLib.ListItem
    Dim d As Double
    ListView1.View = lvwReport

With ListView1.ColumnHeaders
        .Add Text:="Number"
        .Add Text:="Date"
    End With

' Fill some data in listview
    With ListView1.ListItems
        Do While .Count < 1000
            Set oListItem = .Add(Text:="Item: " & .Count + 1)
            d = Rnd * 37300 ' Add some random dates
            oListItem.ListSubItems.Add(Text:=CDate(d)).Tag = d
        Loop
    End With
End Sub

Private Sub ListView1_ColumnClick(ByVal ColumnHeader As MSComctlLib.ColumnHeader)
    Dim oListItem As MSComctlLib.ListItem
    If ColumnHeader.Index = 2 Then
        For Each oListItem In ListView1.ListItems
            oListItem.SubItems(1) = _
          Format$(oListItem.ListSubItems(1).Tag, _
               "yyyymmddHHMMSS")
        Next oListItem
    End If

With ListView1
        .SortKey = ColumnHeader.Index - 1
        .Sorted = True
        If .SortOrder = lvwAscending Then
            .SortOrder = lvwDescending
        Else
            .SortOrder = lvwAscending
        End If
    End With

If ColumnHeader.Index = 2 Then
        For Each oListItem In ListView1.ListItems
            oListItem.SubItems(1) = _
              CDate(oListItem.ListSubItems(1).Tag)
        Next oListItem
    End If
End Sub