Search For XML Nodes Using XPath

Category:

ASP, HTML and XML

Type:

Snippets

Difficulty:

Intermediate

Author:

Anne-Lise Pasch

Version Compatibility: Visual Basic 6, Visual Basic 5

More information:

A function to search subnodes for a tagname/text combination. Needs a reference to Microsoft XML Parser. See comments for example.

Instructions: Copy the declarations and code below and paste directly into your VB project.

Declarations:
' (None)

Code:

Public Function SearchForNodes(ByVal strXML As String, _
  ByVal strTag As String, ByVal strSearchText As String) _
  As DOMDocument
  
'Will Search an XML String for a Tag-value pair and return
'the entire node containing that pair in the form
'of a DOM Document:

'REQUIRES REFERENCE TO MSXML

'EXAMPLE:
'Dim objXMLDoc As New DOMDocument
'Dim objXMLFound As DOMDocument
'Dim strXML As String

'Load XML from file
'If objXMLDoc.Load("C:\My Documents\MyXMLFile.xml") Then
    'strXML = objXMLDoc.xml
    'Search for a tag that looks like this in the xml:
    '<User_ID>583</user_id>
    
    'Set objXMLFound = SearchForNodes(strXML, "User_ID", "583")
    
    'Display the Node that was found
    'Debug.Print objXMLFound.xml
'End If

Dim lngIterator As Long
    Dim strResults As String
    Dim objXMLSearchDocument As DOMDocument
    Dim objXMLSearchElements As IXMLDOMSelection
    Dim objXMLSearchElement As IXMLDOMElement
    Dim strXPath As String
    strResults = "<XML>"
    Set objXMLSearchDocument = New DOMDocument
    objXMLSearchDocument.async = False
    objXMLSearchDocument.setProperty "SelectionLanguage", _
       "XPath"
    Call objXMLSearchDocument.loadXML(strXML)
    Set objXMLSearchElements = _
        objXMLSearchDocument.getElementsByTagName(strTag)
    If objXMLSearchElements.length > 0 Then
        Set objXMLSearchElement = objXMLSearchElements.Item(0)
        Do Until Len(objXMLSearchElement.parentNode.baseName) _
             = 0
            strXPath = "/" + _
              objXMLSearchElement.parentNode.baseName + strXPath
            Set objXMLSearchElement = _  
              objXMLSearchElement.parentNode
        Loop
        Set objXMLSearchElement = Nothing
        strXPath = strXPath + "[" + strTag + " = '" + _
            strSearchText + "']"
    End If
    Set objXMLSearchElements = Nothing
    If Len(strXPath) > 0 Then
        Set objXMLSearchElements = _
           objXMLSearchDocument.selectNodes(strXPath)
 
       If objXMLSearchElements.length > 0 Then 
            For lngIterator = 0 To _ 
               (objXMLSearchElements.length - 1)
                strResults = strResults + _
                objXMLSearchElements.Item(lngIterator).xml
            Next lngIterator
        End If
        Set objXMLSearchElements = Nothing
    End If
    Set objXMLSearchDocument = Nothing
    strResults = strResults + "</xml>"
    Set objXMLSearchDocument = New DOMDocument
    objXMLSearchDocument.async = False
    Call objXMLSearchDocument.loadXML(strResults)
    Set SearchForNodes = objXMLSearchDocument
    Set objXMLSearchDocument = Nothing
End Function