Automatically Create an HTML Navigation Bar Based on Directory Hierarchy

Category:

ASP, HTML and XML

Type:

Snippets

Difficulty:

Intermediate

Author:

Juha

Version Compatibility: ASP

More information:

This ASP code creates a hiearchal navigation bar based on the directory structure: For example, if this code is included in the page http://foo/Documents/Studies/Personal/Default.asp, it will display a navigation bar that looks like:

"MAIN | Documents | Studies | Personal"

Instructions: Copy the declarations and code below and paste directly into your VB project.

Declarations:
' (None)

Code:

<%
Dim fullPath, lenPath, StartSpot, mainDoc

mainDoc = "MAIN" 'What do you wish to call the default home page?
fullPath = Replace(Request.ServerVariables("Path_Info"),"Default.asp","") ' This is the current full URL 
   'path, excluding the default document
lenPath = Len(fullPath)
fullPath = Mid(fullPath,2,LenPath) 'Here we just snip the 
'leading / away.

lenPath = (lenPath -1) ' because we just snipped the above char.
StartSpot = 1 'This is where we start looking. 
     'StartSpot is updated as we go on.

'If the page is some other than the main page "/Default.asp", 
'display link to it.

If fullPath <> "" Then _
  Response.Write "<a href=""/Default.asp"">" & mainDoc _
  & "</a> | "

'This loop is the actual script that parses the current URL.
Dim i, dotA, endSpot, partDirPath, wholeDirPath

For i = 1 to lenPath
	dotA = Mid(fullPath,i,1)
	If dotA = "/" Then ' Found first start character
		EndSpot = i 'Mark the end
		partDirPath = _
              Mid(fullPath,startSpot,endSpot-(startSpot-1))
		wholeDirPath = wholeDirPath & partDirPath

Response.Write "<a href=""/" & _
                wholeDirPath & """>" &  _
                Replace(partDirPath,"/","") _
               & "</a> | "

StartSpot = (i+1) 'Set new starting 
                     'character, which is next to current.
	End If
Next
%>