Auto-Complete Combo Box that Prevents User from Selecting Items Not in List

Category:

Forms and Controls

Type:

Snippets

Difficulty:

Intermediate

Author:

Henry aka PiR82k Erich III

Version Compatibility: Visual Basic 6

More information:

Modified code found in MS MSDN Lib. Prevents person from typing in item that is not already in list, even when combo box style is not set to drop-down list. This provides an auto-complete effect.

Instructions: Copy the declarations and code below and paste directly into your VB project.

Declarations:
Option Explicit #If Win32 Then Private Declare Function SendMessage Lib "user32" Alias _ "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, _ ByVal wParam As Long, lParam As Long) As Long #Else Private Declare Function SendMessage Lib "User" ( _ ByVal hwnd As Integer, ByVal wMsg As Integer, _ ByVal wParam As Integer, lParam As Any) As Long #End If Private Const WM_SETREDRAW = &HB Private msOldString As String ' module level global Private miStart As Integer ' module level global Private miLength As Integer ' module level global

Code:

Private Sub Combo1_KeyUp(KeyCode As Integer, Shift As Integer)
    Dim sComboText As String
    Dim iLoop As Integer
    Dim sTempString As String
    Dim lReturn As Long
    Dim bInList As Boolean
    Dim sItem
    
  If Not KeyCode = Asc(vbTab) And Not KeyCode = vbKeyShift And _
      Not KeyCode = vbKeyLeft And Not KeyCode = vbKeyRight And _
      Not KeyCode = vbKeyHome And Not KeyCode = vbKeyEnd Then
       
        bInList = False
        
        With Combo1
            sTempString = .Text
            If Len(sTempString) = 1 Then sComboText = sTempString
            lReturn = SendMessage(.hwnd, WM_SETREDRAW, False, 0&)
            For iLoop = 0 To (.ListCount - 1)
                sItem = .List(iLoop)
                If UCase((sTempString & Mid$(sItem, _
                 Len(sTempString) + 1))) = UCase(sItem) Then
                    .ListIndex = iLoop
                    .Text = sItem
                    msOldString = sItem
                    miStart = Len(sTempString)
                    .SelStart = miStart
                    miLength = Len(sItem) - (Len(sTempString))
                    .SelLength = miLength
                    sComboText = sComboText & Mid$(sTempString, _
                        Len(sComboText) + 1)
                    bInList = True
                    Exit For
                End If
            Next iLoop
            
            If Not bInList Then
                .Text = msOldString
                .SelStart = miStart
                .SelLength = miLength
            End If
            
            lReturn = SendMessage(.hwnd, WM_SETREDRAW, True, 0&)
        End With
    End If
   End Sub

Private Sub Form_Load()
 'JUST SAMPLE FOR DEMO PURPOSES
 'YOU CAN OBVIOUSLY ADD WHAT YOU NEED
 'TO ADD HERE
    With Combo1
        .AddItem "Blue"
        .AddItem "Green"
        .AddItem "Yellow"
        
        .ListIndex = 0
        .Text = .List(0)
        .SelStart = 0
        .SelLength = Len(.Text)
        msOldString = .Text
        miStart = 0
        miLength = .SelLength
    End With
End Sub